home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 27 / CU Amiga Magazine's Super CD-ROM 27 (1998)(EMAP Images)(GB)[!][issue 1998-10].iso / CUCD / Programming / JForth / JTools / Janim / unvscomp.asm < prev    next >
Encoding:
Assembly Source File  |  1991-03-27  |  4.9 KB  |  159 lines
  1. \ JForth Port of Jim Kent's unvscomp.asm
  2. \ by Martin Kees
  3. \ The original docs:
  4. \ unvscomp.asm  Copyright 1987 Dancing Flame all rights reserved.
  5. \
  6. \ This file contains a single function which is set up to be called from
  7. \ C.  Ie the parameters are on the stack instead of registers.
  8. \       decode_vkplane(in, out, linebytes)
  9. \ where in is a bit-plane's worth of vertical-byte-run-with-skips data
  10. \ and out is a bit-plane that STILL has the image from last frame on it.
  11. \ Linebytes is the number of bytes-per-line in the out bitplane, and it
  12. \ should certainly be noted that the external pointer variable ytable
  13. \ must be initialized to point to a multiplication table of
  14. \ 0*linebytes, 1*linebytes ... n*linebytes  before this routine is called.
  15. \ 
  16. \ The format of "in":
  17. \   Each column of the bitplane is compressed separately.  A 320x200
  18. \   bitplane would have 40 columns of 200 bytes each.  The linebytes
  19. \   parameter is used to count through the columns, it is not in the
  20. \   "in" data, which is simply a concatenation of columns.
  21. \
  22. \   Each columns is an op-count followed by a number of ops.
  23. \   If the op-count is zero, that's ok, it just means there's no change
  24. \   in this column from the last frame.
  25. \   The ops are of three classes, and followed by a varying amount of
  26. \   data depending on which class.
  27. \       1. Skip ops - this is a byte with the hi bit clear that says how many
  28. \          rows to move the "dest" pointer forward, ie to skip. It is non-
  29. \          zero
  30. \       2. Uniq ops - this is a byte with the hi bit set.  The hi bit is
  31. \          masked down and the remainder is a count of the number of bytes
  32. \          of data to copy literally.  It's of course followed by the
  33. \          data to copy.
  34. \       3. Same ops - this is a 0 byte followed by a count byte, followed
  35. \          by a byte value to repeat count times.
  36. \   Do bear in mind that the data is compressed vertically rather than
  37. \   horizontally, so to get to the next byte in the destination (out)
  38. \   we add linebytes instead of one!
  39. \
  40. anew task_decode
  41.  
  42. 400 value ytablesize          \ defaults for 320x200 display
  43.  40 value ybytesize  
  44. v: ytable ytable OFF   
  45.  
  46.  
  47. : calc.ytable ( -- )
  48.   ytable freevar
  49.   MEMF_PUBLIC ytablesize allocblock ytable !
  50.   ytable @ IF-NOT ." No memory for ytable"
  51.                 abort
  52.            THEN
  53.   0
  54.   ytablesize 2/ 0 do dup 
  55.                      ytable @ i 2* + w! 
  56.                      ybytesize +
  57.                   loop
  58.   drop
  59. ;
  60.  
  61.  
  62. ASM decode_vkplane ( in out linebytes --- )
  63.     movem.l    a2-a3/d5,-(rp)  ; save registers 
  64.     move.l    (dsp)+,a2
  65.     adda.l  a4,a2 
  66.     move.l    (dsp)+,a0
  67.     adda.l  a4,a0
  68.     move.w    d7,d2
  69.     move.l  (dsp)+,d7
  70.     callcfa ytable
  71.     move.l  $0(a4,tos.l),tos 
  72.     move.l  d7,a3
  73.     adda.l  a4,a3
  74.     move.w    d2,d4    \ make a copy of linebytes to use as a counter
  75.     bra    1$    \ And go to the "columns" loop
  76.     
  77. 2$:    move.l    a2,a1     \ get copy of dest pointer
  78.     clr.w    d0      \ clear hi byte of op_count
  79.     move.b    (a0)+,d0  \ fetch number of ops in this column
  80.     bra    3$      \ and branch to the "op" loop.
  81.  
  82. 4$:    clr.w    d1      \ clear hi byte of op
  83.     move.b    (a0)+,d1  \ fetch next op
  84.     bmi    5$        \ if hi-bit set branch to "uniq" decoder
  85.     beq     6$      \ if it's zero branch to "same" decoder
  86.  
  87.               \ otherwise it's just a skip
  88.     add.w    d1,d1      \ use amount to skip as index into word-table
  89.     adda.w    0(a3,d1.w),a1
  90.     dbra.w    d0,4$     \ go back to top of op loop
  91.     bra    7$        \ go back to column loop
  92.  
  93.             \ here we decode a "vertical same run"
  94. 6$:    move.b    (a0)+,d1  \ fetch the count
  95.     move.b    (a0)+,d3  \ fetch the value to repeat
  96.     move.w    d1,d5     \ and do what it takes to fall into a "tower"
  97.     asr.w    #3,d5     \ d5 holds # of times to loop through tower
  98.     and.w    #7,d1     \ d1 is the remainder
  99.     add.w    d1,d1
  100.     add.w    d1,d1
  101.     neg.w    d1
  102.     jmp    34(pc,d1.w)            \ why 34?  8*size of tower
  103.                                      \ instruction pair, but the extra 2's
  104.                                      \ pure voodoo.
  105. 8$:    move.b    d3,(a1)
  106.     adda.w    d2,a1
  107.     move.b    d3,(a1)
  108.     adda.w    d2,a1
  109.     move.b    d3,(a1)
  110.     adda.w    d2,a1
  111.     move.b    d3,(a1)
  112.     adda.w    d2,a1
  113.     move.b    d3,(a1)
  114.     adda.w    d2,a1
  115.     move.b    d3,(a1)
  116.     adda.w    d2,a1
  117.     move.b    d3,(a1)
  118.     adda.w    d2,a1
  119.     move.b    d3,(a1)
  120.     adda.w    d2,a1
  121.     dbra.w    d5,8$
  122.     dbra.w    d0,4$
  123.     bra.l    7$
  124.  
  125.                           \ here we decode a "unique" run
  126. 5$:    and.b    #$7f,d1   \ setting up a tower as above....
  127.     move.w    d1,d5
  128.     asr.w    #3,d5
  129.     and.w    #7,d1
  130.     add.w    d1,d1
  131.     add.w    d1,d1
  132.     neg.w    d1
  133.     jmp    34(pc,d1.w)
  134. 9$:    move.b    (a0)+,(a1)
  135.     adda.w    d2,a1
  136.     move.b    (a0)+,(a1)
  137.     adda.w    d2,a1
  138.     move.b    (a0)+,(a1)
  139.     adda.w    d2,a1
  140.     move.b    (a0)+,(a1)
  141.     adda.w    d2,a1
  142.     move.b    (a0)+,(a1)
  143.     adda.w    d2,a1
  144.     move.b    (a0)+,(a1)
  145.     adda.w    d2,a1
  146.     move.b    (a0)+,(a1)
  147.     adda.w    d2,a1
  148.     move.b    (a0)+,(a1)
  149.     adda.w    d2,a1
  150.     dbra.w    d5,9$      \ branch back up to "op" loop
  151. 3$:     dbra.w    d0,4$      \ branch back up to "column loop"
  152.  
  153.     \  now we've finished decoding a single column
  154. 7$:    addq.l    #1,a2  \ so move the dest pointer to next column
  155. 1$:    dbra.w    d4,2$  \ and go do it again what say?
  156.     movem.l    (rp)+,a2-a3/d5
  157.     move.l  (dsp)+,d7
  158. end-code
  159.